@program wwiv6.muf
1 1000 d
i
$include $lib/alynna
$def tname target @ name 
$def tsex target @ "sex" getpropstr dup "" stringcmp if 1 strcut pop toupper else pop "?" then
$def tspec target @ "species" getpropstr
$def tstat target @ "status" getpropstr
$def tonline target @ onlinetime 60 / dhm
$def tidle target @ idletime stimestr 
$def tloc target @ location
$def YES? tolower "y*" smatch

: online_array_sorted
$ifdef __fuzzball__
 ( FB6 doesnt work )
 {
  {
  online_array foreach swap pop name repeat
  }array SORTTYPE_NOCASE_ASCEND array_sort 
 foreach swap pop pmatch repeat
 }array
$else
 ( Proto does )
 online_array SORTTYPE_NOCASE_ASCEND array_sort
$endif
;
 
: wheader ( -- )
  "^WHITE^^BGREEN^Name          ^BBROWN^S Species              ^BCYAN^    Time IDL STA ^BBLUE^Location name               ^NORMAL^" 
;
: wfooter ( -- )
  {
  "^WHITE^^BBLUE^-/@< Who/Where/Idle by Alynna >@\\-----"
  { me @ location numplayers "/" concount "/" #0 "/_sys/max_connects" getprop "------------------" }cat 19 strcut pop
  "[ " strcat "%x %X" systime timefmt strcat " ]-^NORMAL^"
  }cat
;
 
: main
var target
{
wheader
online_array_sorted foreach target ! pop
target @ "D" flag? not target @ "_invisible?" getpropstr yes?
target @ location "D" flag? not target @ location "_invisible?" getpropstr yes? or or or if
 { "^GREEN^" tname 13 lj " ^YELLOW^" tsex " " tspec 21 lj "^CYAN^" tonline 8 rj " " tidle 3 lj " " tstat 3 lj " ^WHITE^"
  target @ "H" flag? target @ "_private?" getpropstr yes? 
  target @ location "H" flag? target @ location "_private?" getpropstr yes? or or or if
   "<Private>"
  else
  target @ location me @ location dbcmp if
   "<Here>"
  else
   tloc 
  then
 then
 "^NORMAL^" 
 }cat
then
repeat
wfooter
} array_make atellme
;
.
c
q