@program reconnect.muf
1 10000 d
i
( reconnect.muf  --  6/16/94  by Squirrelly )
(
    Usage:  reconnect <User name> <Password>
    Allows a user to reconnect to a new character as if they had done
    a QUIT and then logged back in as that character.
    If connected more than once, it will attempt to reconnect the most
    recent connection.
)

lvar DESCR

: main
    dup if dup "#help" smatch else 1 then if
        "Usage:  " COMMAND @ strcat " <player name> <password>" strcat
        .tell
        $ifdef __version<Muck2.2fb5.47
            "Effectivly does a QUIT and attempts to log you in as" .tell
            "the new character.  Note:  If you give a valid character"
            .tell
            "name but invalid password, you will get an error or" .tell
            "or possibly be disconnected." .tell
        $else
            "Effectivly does a QUIT and attempts to log you in as "
            "the new character." strcat .tell
        $endif
        pop exit
    then
    ME @ player? not if
        "You are not a connected player." .tell
        pop exit
    then
    ME @ "me" match dbcmp not if
        "Reconnect -- Security check failure -- Aborted" .tell
        pop exit
    then
    ME @ descriptors
    dup not if
        "You are not a connected player." .tell
        pop pop exit
    then
    over DESCR !
    .popn
    " " .split swap
    dup if
        dup "#[0-9]*" smatch if
            dup .atodbref
            dup player? if
                swap pop
            else
                pop .pmatch
            then
        else
            .pmatch
        then
    else
        pop #-1
    then
    dup player? not if
        "Either that player does not exist, or has a different password."
        .tell
        pop pop exit
    then
    swap DESCR @ rot rot
    $ifndef __version<Muck2.2fb5.47
        over over checkpassword not if
            "Either that player does not exist, or has a different "
            "password." strcat .tell
            pop pop pop exit
        then
    $endif
    descr_setuser
    not if
        "Reconnect -- Failed (Error)" .tell
    then
;
.
c
q