@program noteReq.muf
1 10000 d
i
$include $lib/alynna
lvar param
lvar target

: noteReq.set
me @ "/~/notereq" param @ setprop
{ "^GREEN^Note request set to: ^ ^" param @ }tell
;

: noteReq.clear
me @ "/~/notereq" 0 setprop
{ "^YELLOW^Note request cleared." }tell
;

: noteReq.show
target @ "/~/notereq" getprop dup var! x not if
 { "^YELLOW^" target @ " has no current note request." }tell
else
 { target @ " currently requests the following Note" }cat header tellme
 x @ wrap78 atellme
 "NoteRequest 1.0" footer tellme
then 
;

: noteReq.help
{
"NoteRequest - (C) 2006 Alynna Trypnotk, Haven MUCK"
" Allows you to suggest a note you would like to have added to you,"
" when you participate in TPs.  It gives staff ideas about where your"
" character is developing."
" "
"Syntax:"
" notereq 			View your current note"
" notereq <person>		(WIZ) View someones note"
" notereq #set <text>		Enter a note request"
" notereq #clear		Delete your note request"
" notereq #help			Duh..."
}array atellme
;

: moan
param !
param @ not if "me" param ! then
param @ case
 "#set *" smatch when param @ " " split swap pop param ! noteReq.set exit end  
 "#clear" smatch when param @ " " split swap pop param ! noteReq.clear exit end  
 "#help" smatch when noteReq.help exit end
 default pop
  me @ mlevel 5 < if "me" param ! then
  param @ pmatch target !
  target @ int 0 < if { "^RED^I couldn't find anyone named '" param @ "'.  Please hang up and try again." }tell exit then
  noteReq.show
 end
endcase   
;
.
c
q