@program NetWWI.muf
1 10000 d
i
$include $lib/alynna
$include $p.net/sys

: .net.getEntry[ s:cguid s:muckname s:source s:target a:payload -- ]
payload @ 0 [] var! myname
payload @ 1 [] var! sex
payload @ 2 [] var! species
payload @ 3 [] var! oltime
payload @ 4 [] var! idlet
payload @ 5 [] var! stat
"fname" muckname @ getmuck var! fname
target @ {
 "^GREEN^"    myname @ 14 lj
 "^YELLOW^"   sex @ 0 unparse_ansi 1 unparse_ansi 2 unparse_ansi 3 unparse_ansi capitalize 1 lj " "
              species @ 0 unparse_ansi 1 unparse_ansi 2 unparse_ansi 3 unparse_ansi capitalize 21 lj
 "^CYAN^"     oltime @ 60 / dhm 8 lj " "
              idlet @ stimestr 3 lj " "
              stat @ 0 unparse_ansi 1 unparse_ansi 2 unparse_ansi 3 unparse_ansi 3 lj " "
 "^PURPLE^"   fname @ " (" muckname @ ")"
}cat ansi_notify
target @ "_nwwi/count" over over getprop ++ setprop
; PUBLIC .net.getEntry

: .net.requestData[ s:cguid s:muckname s:source s:target a:payload -- ]
online_array foreach var! cur pop
 cur @ "D" flag? cur @ "H" flag? or if continue then
 { cur @ name 
   cur @ "~sex" getprop dup not if pop
    cur @ "_sex" getprop dup not if pop
     cur @ "sex" getprop dup not if pop "?" then
    then
   then 
   cur @ "~species" getprop dup not if pop
    cur @ "_species" getprop dup not if pop
     cur @ "species" getprop dup not if pop "?" then
    then
   then
   cur @ onlinetime
   cur @ idletime
   cur @ "~status" getprop dup not if pop
    cur @ "_status" getprop dup not if pop
     cur @ "status" getprop dup not if pop "?" then
    then
   then
  }array me @ source @ muckname @ "wwi" "getEntry" p.callback
0 sleep
repeat
; PUBLIC .net.requestData

: main
background
me @ "_nwwi/count" 0 setprop
{ "^WHITE^^BGREEN^Name          ^BBROWN^S Species              ^BCYAN^    Time IDL STA ^BBLUE^MUCK name                ^NORMAL^" }tell
0 array_make "wwi" "requestData" p.bcast
5 sleep
{
 "^WHITE^^BBLUE^-/@< NetWWI by Alynna >@\\-------------"
 { concount "/" #0 "/_sys/max_connects" getprop "/" me @ "_nwwi/count" getprop "------------------" }cat 19 strcut pop
 "[ " strcat "%x %X" systime timefmt strcat " ]-^NORMAL^"
}tell
me @ "_nwwi/count" 0 setprop
;
.
c
q