@program logtools.muf
1 10000 d
i
$include $lib/alynna
lvar param

$def logname target @ "~log/name" getpropstr
$def logpath { "public_html/logs/" target @ "-" logname ".txt" }cat
$def logurl { "http://muck.animaltracks.net:" "wwwport" sysparm "/logs/" target @ "-" logname ".txt" }cat
$def parseargs param @ " " split var! args pop

: get_logtargets
{
me @ location contents_array foreach swap pop 
 dup player? if 
  dup "~log/on" getprop not if pop then 
 else pop then
repeat
}array
;

: addlog[ str:line -- ]
var target
get_logtargets foreach target ! pop
 { line @ 10 itoc }cat logpath fappend pop
repeat
;

: log.on
me @ "~log/on" 1 setprop
">>> Logging is now turned ON" tellme
;

: log.off
me @ "~log/on" 0 setprop
">>> Logging is now turned OFF" tellme
;

: log.new
me @ var! target
parseargs
args @ not if
 "Format: log new <logname>" tellme exit
then
{ "Are you sure you want to delete the log called '" logname "'?" }cat tellme
read "Y*" smatch if 
 logpath frm 
 "Deleted." tellme
 args @ "" "/" subst "" ":" subst "" " " subst args !
 me @ "~log/name" args @ setprop
 { "New log started at " logurl }cat tellme
 log.on
else
 "Log not deleted." tellme
then
;

: log.reset
me @ var! target
{ "Are you sure you want to reset the log called '" logname "'?" }cat tellme
read "Y*" smatch if 
 logpath frm 
 "Log reset." tellme
else
 "Log not reset." tellme
then
;

: log.url
me @ var! target
{ ">>> Your current log can be found at: " logurl }tell
;

: log.end
log.off
log.url
;

: log.help
{ 
"LogTools (C) 2003 Alynna Trypnotk" 
" "
" log                        Read this help"
" log help                   Same thing"
" log new <title>            Start a new log with this title, and start logging"
" log reset                  Clear your current log"
" log off                    Pause your log"
" log on                     Resume your log"
" log url                    Shows you where you can see the log or pick it up"
" log end                    Turns off logging and displays the pickup URL"
" llook <something>          Alot like look, only to the logfile"
" lnote <text>               Sends the text to the log"
" "
"Right now it picks up anything you say, pose or spoof."
}array atellme
;

: log.say
parseargs
{ me @ ": " args @ strip }cat addlog
;

: log.pose
parseargs
{ me @ args @ "'*" smatch not if " " then args @ strip }cat addlog
;

: log.spoof
parseargs
{ "[" me @ "] " args @ strip }cat addlog
;

: log.look
var target
param @ not if "here" param ! then
param @ resolve target !
target @ int 0 < if "^YELLOW^I don't see that here.^NORMAL^" tellme exit then
{ target @ }cat dup addlog "<Log> Added description of '" swap strcat "' to log." strcat tellhere
{ target @ "_/de" "LOG" 0 parseprop }cat addlog
;

: log.note
param @ addlog
;

: main
param !
command @ tolower case 
 "log" smatch when 
  param @ tolower case
   "new *" smatch when log.new end
   "on" smatch when log.on end
   "off" smatch when log.off end
   "url" smatch when log.url end
   "end" smatch when log.end end
   "reset" smatch when log.reset end
   "{help|#help}" smatch when log.help end 
   not when log.help end 
  endcase
 end
 "llook" smatch when log.look end
 "lnote" smatch when log.note end
 default pop
 param @ tolower case
   "say *" smatch when log.say end
   "pose *" smatch when log.pose end
   "spoof *" smatch when log.spoof end
 endcase
end
endcase
;
.
c
q