$include $lib/rp
$include $lib/alynna
$def PERIOD 21600
$def }t }cat command @ pretty tellme
$def }w }cat "!wc #" swap strcat #21 swap force
lvar param

: lpvote
param @ not if
 { "Syntax: +lpvote <a TP runner>" }t exit
then
systime me @ "lptime" getstat - PERIOD < if
 { "You have recently voted for a scene runner.  You may vote again in " PERIOD systime me @ "lptime" getstat - - timex "." 
 }t exit
then 
param @ pmatch dup toint 0 < if pop
 { "Target not found." }t exit
then var! target
target @ me @ dbcmp if
 { "You can't LPVote for yourself, fool!  Staff is being informed of your infraction." }t
 { "<Ethics Violation> " me @ unparseobj " tried to LPVote for themselves." }w
 exit 
then
target @ me @ alt? if
 { "You can't LPVote for your alts, fool!  Staff is being informed of your infraction." }t
 { "<Ethics Violation> " me @ unparseobj " tried to LPVote for their alt " target @ unparseobj "." }w
 exit 
then
target @ "~status" getprop "{TP|WIZ|HS}" smatch not if
 { "The target specified is not running a TP." }t exit 
then
me @ "lptime" systime setstat
me @ "lptarget" target @ setstat
target @ "lp" over over getstat 1 + setstat
{ "You give a League Point vote to " target @ "." }t
target @ { me @ " gives a League Point vote to you." }cat command @ pretty ansi_notify
{ "<LP> " me @ " votes a League Point for " target @ "." }w
; SAFECALL lpvote

: lp
param @ if
 me @ mlevel 5 >= if 
  param @ pmatch dup toint 0 < if pop
   { "Target not found." }t exit
  then
 else
  me @
 then
else
 me @ 
then var! target
target @ "lptarget" getstat if
{ target @ " has " target @ "lp" getstat "LP, and last voted for " target @ "lptarget" getstat " " systime target @ "lptime" getstat - timex " ago." }t
else
{ target @ " has " target @ "lp" getstat "LP." }t
then 
; SAFECALL lp

: main
param !
command @ "" "+" subst "." "/" subst command !
prog command @ cancall? if
 prog command @ call
else
 { "Your icon(s) " command @ " have no default tool." }tell
then
;