@program $muf/inline
1 1000 d
i
( Inline primitive, execute MUF within MUF )
( (C) 2003 Alynna Trypnotk - alynna@animaltracks.net
  Release terms: GNU GPL v2
  http://www.gnu.org/copyleft/gpl.html
  Just tell me where you got me, where your using this program (host/port)
  and distribute your changes under the same terms as you got them [GNU GPL v2] )
( 1. @reg muf-inline=muf/inline
  2. $include $muf/inline
  3. 4 "3 +" inline
  4. ???
  5. Profit!
)
: inline[ str:quick -- dirty ]
var dirty
{ "$include $lib/alynna"
  "$include $lib/rp"
  "$include $lib/rps"
  "$include $lib/rps2"
  "$include $lib/rps3"
  ": quick"
     quick @
  "; PUBLIC quick"
}array quick !
frand ftostr "" "0." subst newprogram dirty !
dirty @ caller owner setown
dirty @ 1 quick @ program_insertlines pop
dirty @ 0 compile not if
 dirty @ recycle
 "INLINE: Error compiling MUF code" abort
 exit
then
depth try
 dirty @ "quick" call
catch
 dirty @ recycle
 "INLINE: " swap strcat abort
 exit
endcatch
dirty @ recycle
; WIZCALL inline
$libdef inline
: main inline ;
.
c
q