@program helplookup.htmuf
1 10000 d
i
$include $lib/alynna
$include $lib/cgiparse
$include $web/login
INCLUDE_WEBVARS

: array_getfile[ str:filename -- arr:file ]
0 var! filepos
0 var! filesize
0 array_make var! file
filename @ fsize filesize !
{
 begin
  filename @ filepos @ 10 itoc freadto "" 13 itoc subst dup not if pop filepos ! else swap filepos ! then
  filepos @ filesize @ >= if break then
  depth 1000 >= if }array file @ dup array_count rot array_insertrange file ! { then
 repeat
}array file @ dup array_count rot array_insertrange 
;
 
: main
var file
var check
var item
var line
var linenum
var found
var lookup 
var output

PARSE_HEADERS
postdata @ if
 "file" raw if
  "file" post "lasthelpfile" setwebuser
 else
  "help" "lasthelpfile" setwebuser
 then
then
{ WWW "_/www/header" mpilist }w
{ "<center><H3>ProtoMUCK Manual</H3><p/>" }w
{ "<FORM ACTION='http://" "host" head wpath @ "' METHOD='POST' NAME='F'>" }w
{ "Find <input name='HELPLOOKUP' size=32 maxlength=128> in " }w
{ "<INPUT type='radio' value='help' name='file'" "lasthelpfile" getwebuser astr "help" smatch if " checked" then ">Help" }w
{ "<INPUT type='radio' value='mpi' name='file'" "lasthelpfile" getwebuser astr "mpi" smatch if " checked" then ">MPI" }w
{ "<INPUT type='radio' value='muf' name='file'" "lasthelpfile" getwebuser astr "muf" smatch if " checked" then ">MUF" }w
{ "<INPUT type='radio' value='sysparms' name='file'" "lasthelpfile" getwebuser astr "sysparms" smatch if " checked" then ">Sysparms" }w
{ "<INPUT TYPE='SUBMIT' SIZE=320 VALUE='Search' NAME='SUBMIT'>" }w
{ "<TEXTAREA ROWS=16 COLS=80 NAME='HELPTEXT'>" }w
postdata @ if
 "file" post case
  "help" smatch when "$HELP.TXT" array_getfile file ! end
  "mpi" smatch when "$MPIHELP.TXT" array_getfile file ! end
  "muf" smatch when "$MAN.TXT" array_getfile file ! end
  "sysparms" smatch when "$SYSPARMS.TXT" array_getfile file ! end
  default "help" "lasthelpfile" setwebuser "$HELP.TXT" array_getfile file ! end
 endcase
 "helplookup" post lookup !
 lookup @ if
  lookup @ strlen 2 > if
   file @ foreach line ! linenum !
   line @ "~*" smatch if 
    0 output ! 1 check ! 
    continue 
   then
   check @ if 
    line @ lookup @ instring if 
     1 output ! 1 found !
    then 
   0 check ! continue 
   then
   output @ if 
    { line @ }w 
   then
   repeat
  else
  { "The search parameters were less than 3 characters ..." }w
  then
 else
   { "No search parameters specified..." }w
 then
found @ not if { "Could not find '" lookup @ "' in the manual." }w then
then
{ "</TEXTAREA>" }w
{ "</FORM>" }w
{ WWW "_/www/footer" mpilist }w
;
.
c
q