@program deathknell.muf==tmp/prog1
1 1000 d
i
( Deathknell.muf, the IRCBOT for MUCKS  )
( Lamers check in, they dont check out. )
: help
{
"DeathTable, the IRCBOT for MUCKS.  Lamers check in, they dont check out."
"(C) 2003 Alynna Trypnotk -- Release terms GNU GPL V2"
" "
"Syntax:"
" @exile <player>                                 Boot and ban <player>"
" @hostban <hostmask with wildcards>=<message>    Ban hostmask with message"
" @hostban <hostmask with wildcards>=             Remove ban"
" @banlist                                        Check all bans"
}array { me @ }array array_ansi_notify
;

$include $lib/alynna
$def log_status logstatus
lvar param

$def AVATAR #3
 
: hostban
var hostmask
var message
param @ "=" explode 2 = not if
 { "Format: " command @ " <hostmask>=<message>" }cat "Hostban" pretty tellme
 exit then
hostmask ! message !
#0 { "/@/death-table/" hostmask @ }cat message @ setprop
message @ if
  { "Hostban on " hostmask @ " set." }cat "Hostban" pretty tellme
 else
  { "Hostban on " hostmask @ " cleared." }cat "Hostban" pretty tellme
 then
;

: banlist
var item
var value
#0 "/@/death-table/" array_get_propvals foreach value ! item !
  { item @ 40 lj value @ }cat tellme
repeat
;

: exile
var target
var tdescr
param @ not if
 { "Format: " command @ " <target>" }cat "Exile" pretty tellme
 exit then
param @ pmatch target !
target @ player? if
target @ descr_array foreach tdescr ! pop
 #0 
 { "/@/death-table/" tdescr @ descrhost dup "." instr strcut swap pop "*." swap }cat 
 { "Your host was @exiled by a wizard." }cat
 setprop
 tdescr @ { "You, " target @ "@" tdescr @ descrhost ", have been @exiled!  Been nice knowing you." }cat "Exile" pretty ansi_notify_descriptor
 tdescr @ descrboot
 AVATAR { "wc " target @ "@" tdescr @ descrhost dup "." instr strcut swap pop "*." swap " was exiled by " me @ }cat force
 { { target @ " @exiled by " me @ ": " tdescr @ descrhost dup "." instr strcut swap pop "*." swap }cat "Siteban" pretty tellme
repeat
then
;

: deathtable
var item
var value
0 sleep
#0 "/@/death-table/" array_get_propvals foreach value ! item !
 descr descrhost item @ smatch descr descripnum item @ smatch or if
  descr value @ "DeathTable" pretty ansi_notify_descriptor
  descr descrboot
  { "Descriptor " descr " booted, matched " item @ " with message '" value @ "'." }cat log_status
 then 
repeat
;
 
: main
param !
param @ "#h*" smatch if help exit then
command @ "@exile" smatch if exile exit then
command @ "@hostban" smatch if hostban exit then
command @ "@banlist" smatch if banlist exit then
command @ "Queued event." smatch if deathtable exit then
;
.
c
q
@act @exile;@hostban;@banlist=#0,$tmp/prog1
@propset #0=d:@login/deathtable:$tmp/prog1